#!/bin/sed -nEf

# Copyright 2018 - 2019 Paul Hänsch
# 
# Permission to use, copy, modify, and/or distribute this software for any
# purpose with or without fee is hereby granted, provided that the above
# copyright notice and this permission notice appear in all copies.
# 
# THE SOFTWARE IS PROVIDED “AS IS” AND THE AUTHOR DISCLAIMS ALL WARRANTIES
# WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
# MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY
# SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
# WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
# ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF OR
# IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.

:Escapes
s,\\\\,\\,g; s,\\&,\&,g;
s,\\<,\&lt;,g; s,\\>,\&gt;,g;
s,\\",\&quot;,g; s,\\',\&apos;,g;
s,\\\[,\&#91;,g; s,\\\],\&#93;,g;
s,\\\.,\&#46;,g; s,\\#,\&#35;,g;
s,\\,,g;

:CommentHandle
x; /^<\/!-->/{
  x; /--]/{
    H; s;^(.*)--].*$;\1-->;p;
    g; s;^.*--]([^\n]*)$;\1;
    x; s;^</!-->\n(.*)\n[^\n]*$;\1;; x;
    bCommentEnd
  }
  p; b;
}
x;
:CommentEnd

:shortcuts
s;\[hidden[ \t]+"([^"]*)"[ \t]+"([^"]*)";[input type="hidden" name="\1" value="\2";g;
s;\[checkbox[ \t]+"([^"]*)"[ \t]+"([^"]*)";[input type="checkbox" name="\1" value="\2";g;
s;\[radio[ \t]+"([^"]*)"[ \t]+"([^"]*)";[input type="radio" name="\1" value="\2";g;
s;\[submit[ \t]+"([^"]*)"[ \t]+"([^"]*)";[button type="submit" name="\1" value="\2";g;
s;\[a[ \t]+"([^"]*)";[a href="\1";g;
s;\[img[ \t]+"([^"]*)"[ \t]+"([^"]*)";[img src="\1" alt="\2";g;

s;\[!([^]\[]*)\];<!\1>;g;
s;\[!--([^]\[]*)--\];<!--\1-->;g;

:tags
s;\[([^]\[< \t]+)([^]\[]*)\];<\1>\2</\1>;g;
t tags;

G;
:tagclose
s;^([^]\n]*)\]([^\n]*)\n([^\n]+);\1\3\2;
t tagclose;
h; s;^([^\n]*)\n;;; x; s;\n.*$;;;

:tagopen
s;^([^\[\n]*)\[([^]\[< \t\n]+)([^\n]*);\1<\2>\3\n</\2>;
t tagopen;
G; h; s;^[^\n]*\n+;;; x; s;\n.*$;;;

:attribs
s;class="([^>]+)>[ \t]*\.([^< \t]+);class="\2 \1>;g; t attribs;
s;(<[^/][^>]*)>[ \t]*\.([^< \t]+);\1 class="\2">;g;
s;(<[^/][^>]*)>[ \t]*#([^< \t]+);\1 id="\2">;g;
s;(<[^/][^>]*)>[ \t]*([^ \t=<]+=("[^"]*"|'[^']*'|[^< \t]*));\1 \2>;g;
t attribs;
s;(<input ([^>]+ )?type=(radio|"radio"|'radio')( [^>]+)?)>[ \t]*(checked|selected);\1 checked="checked">;g;
s;(<input ([^>]+ )?type=(checkbox|"checkbox"|'checkbox')( [^>]+)?)>[ \t]*(checked|selected);\1 checked="checked">;g;
s;(<option( [^>]+)?)>[ \t]*(checked|selected);\1 selected="selected">;g;
s;(<select( [^>]+)?)>[ \t]*multiple;\1 multiple="multiple">;g;
t attribs;
s;(<[^/][^>]*>)[ \t]*\.[ \t];\1;g;

s;(<[^/][^>]*>)[ \t]*;\1;g;
# s;(<[^/][^>]*)>[ \t]*</[^>]+>;\1/>;g;
s;(<(br|hr|img|input|link|meta|area|base|col|command|embed|keygen|param|source|track|wbr)[^>]*)>[ \t]*</\1>;\1>;g;

s;<!-->;<!--;;

p; ${g; s;\n+;;g; p;}